需要的元件

• Arduino UNO

• LCD1602

• SD卡模块

• 旋转电位器10kohm

• 杜邦线

• 面包板

• 电阻10kΩ

• Arduino IDE

原理及流程

介绍

在某些系统上，例如3D打印机，存储卡用于保存打印文件。因此，在开始和打印过程中检查存储卡连接非常重要。

因此，如果出现任何连接或卡故障，系统必须能够检测到故障并在系统LCD屏幕上通知用户。

除3D打印机外，此方法还可用于使用存储卡的任何系统或设备。

因此，我们提出了一种电路来测试解决方案，如图1所示。

接下来，我们将创建并解释一种算法，以在执行系统的过程中检测存储卡的连接失败或连接失败。

溶液测试电路。

项目发展

构建代码的逻辑非常简单。我们需要在开始时（无效设置功能）和在代码执行过程中（在循环功能内部）检查卡是否已连接。

如果未检测到卡，则根据图2所示，必须在LCD屏幕上输入一条消息以通知用户。

失败或卡断开消息。

这样，用户将插入卡，系统将再次操作，并显示消息“ Card Connected！”，如图3所示。

留言卡已连接。

系统验证SD卡的状态后，系统将等待用户按下按钮并启动SD卡中10个ADC值的存储处理。此时，它将显示如图4所示的消息。

用户按下按钮以启动存储过程的消息。

用户按下按钮后，系统将在SD卡中存储10单位的ADC值，并在屏幕上显示消息：“正在存储数据...”和“成功完成”，以通知存储过程结束。这些消息如下所示。

存储数据的消息

存储成功完成的消息

完成所有这些过程后，系统返回到循环的开头并再次启动所有逻辑。

此后，我们将介绍并讨论为解决该问题而开发的代码。

编程逻辑

根据下面的代码，插入了所用元素的库：LCD显示屏，SD卡，并声明了代码的所有变量。

#include <SD.h>
#include <SPI.h>
#include <LiquidCrystal.h>
  
File myFile;
  
const int rs = 2, en = 3, d4 = 4, d5 = 5, d6 = 6, d7 = 7;
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);
  
#define AnalogPin A0
  
int pinoSS = 10; // Pin 53 para Mega / Pin 10 para UNO
int DigitalValue = 0;
byte samples = 0;
bool SDCardTest = 0, ControlState = 0, LCDControl = 0;

在此代码块之后，我们将在下面介绍void循环函数。可以看到，显示LCD和串行已初始化。之后，进行了第一个测试，以验证我们的SD卡是否已连接或发生故障。

void setup()
{ 
   Serial.begin(9600); // Define BaundRate
   lcd.begin(16, 2);
   pinMode(pinoSS, OUTPUT); // Declara pinoSS como saída
     delay(500);
   lcd.clear();    
   do
   {
     if (SD.begin()) 
     { // Inicializa o SD Card
       lcd.setCursor(6,0);
       lcd.print("Card");
       lcd.setCursor(3,1);
       lcd.print("Connected!");
       delay(2000);
       SDCardTest = 1;
     } 
       else 
     {
       lcd.clear();
       Serial.println("imprimindo segunda mensagem de erro.");
       lcd.setCursor(1,0);
       lcd.print("Failed or Card");
       lcd.setCursor(2,1);
       lcd.print("disconnected");
       SDCardTest = 0;
     }
   }while(SDCardTest == 0);
     
     lcd.clear();
     lcd.setCursor(0,0);
     lcd.print("Press the button");
     lcd.setCursor(1,1);
     lcd.print("To store data");
}

有一个do-while循环来验证SD卡。在此过程中，系统将对SD卡进行初始化。如果初始化过程正常发生，那么SD卡就没有问题了。但是，如果发生任何问题，系统将初始化SD卡。

这样将在显示屏LCD上显示消息“失败或卡已断开连接”，并且变量SDCardTest的值将为0。该变量将用于控制循环执行时间。

解决问题后，再次连接SD卡，将显示消息“按下按钮以存储数据”。

在此之后，将执行空循环功能中的命令。无效循环函数的代码如下所示。

void loop()
{
          bool Button = digitalRead(8);
  
          if(LCDControl == 0)
          {
           lcd.setCursor(0,0);
           lcd.print("Press the button");
           lcd.setCursor(1,1);
           lcd.print("To store data");
           LCDControl = 1;
          }
         
         if(Button == 0 && ControlState == 1)
         {
           ControlState = 0;  
         }    
         if(Button == 1 && ControlState == 0)
         {
           myFile = SD.open("silicioslab.txt", FILE_WRITE); // Create/Open File the txt
           delay(500);
           lcd.clear();
           lcd.setCursor(4,0);
           lcd.print("Storing");
           lcd.setCursor(4,1);
           lcd.print("data...");
           do
           {              
             DigitalValue = analogRead(AnalogPin);
             myFile.println(DigitalValue);
             delay(400);
             samples++;
           }while(samples < 10);
  
           samples = 0;
  
           lcd.clear();
  
           lcd.setCursor(4,0);
           lcd.print("Finished");
           lcd.setCursor(2,1);
           lcd.print("Successfully");            
           delay(2000);
           myFile.close(); //Close file
           LCDControl = 0;
           ControlState = 0;
         }
  
         do
         {
           if (SD.begin()) 
           {
               SDCardTest = 1;          
           } 
             else
           {
             lcd.clear();
             lcd.setCursor(1,0);
             lcd.print("Failed or Card");
             lcd.setCursor(2,1);
             lcd.print("disconnected");
             SDCardTest = 0; 
             LCDControl = 0;   
             Serial.println("Verificando problema...");     
           }
         }while(SDCardTest == 0);
}

在空循环功能中，将读取按钮的状态以验证我们的用户是否按下了按钮。在读取按钮之后，存在以下情况：

if(LCDControl == 0)
{
  lcd.setCursor(0,0);
  lcd.print("Press the button");
  lcd.setCursor(1,1);
  lcd.print("To store data");
  LCDControl = 1;
}

此条件用于使“按下按钮以存储数据”消息仅显示一次。这样可以防止多次显示文本，并且可能在屏幕上产生奇怪的效果。

此后，如果按下按钮，文件将打开，并且10个值将被保存在SD卡中，并显示“成功完成”消息，以通知该过程完成。

最后，文件将被关闭。因此，系统将再次验证SD卡。

最后

所有需要的文件在下载区均可找到。

via：实时SD卡故障检测系统-Hackster.io